Trouble with Buttons

Flawed Spirit · Post by **Flawed Spirit** » Sun Jun 28, 2009 4:54 am

I'm currently working on a mod that involves an option screen with several buttons, but I can't seem to make it work right. Every time I click a button on that screen, it does absolutely nothing.

Below is a quick script I made just to create a couple of basic buttons, with basic responses. Can anyone see what is wrong with this chunk of code just by glancing at it?

Code: Select all

begin FI_test

short button

if ( MenuMode == 1 )
	return
endif

if ( OnActivate == 1 )
	MessageBox "Choose an option.", "Yes", "No"
	set button to GetButtonPressed

	if ( button == 0 )
		MessageBox "You chose yes."
	elseif ( button == 1 )
		MessageBox "You chose no."
	endif
endif

end FI_test

EDITS: Typo in the code, and I fixed the if statements. Buttons start at 0 I think.

Nanu · Post by **Nanu** » Sun Jun 28, 2009 5:24 pm

You don't have anything to handle when the button isn't being pressed. That's -1 IIRC, I haven't scripted for Meht in ages.

Bloodthirsty Crustacean · Sun Jun 28, 2009 6:15 pm

If in doubt, always scavenge a vanilla script.

For buttons, I find the amuletAundae and similar scripts provide a useful template.

But, in this case, I don't need to check to see the problem.

What's happening is that the game is running the second (non-'Menu Mode') block only on the frame that 'OnActivate' holds true, because it's all contained within that if-clause.

What you need to do is move the "if ( button ==" section out of the OnActivate clause, and into one of its own, "if ( messageOn == 1 )". Then, have the OnActivate clause set messageOn to 1.

Finally, have it so that once a button press is recorded, it sets messageOn to 0.

There you go.

If that doesn't make sense, I can provide the script you need.

Flawed Spirit · Post by **Flawed Spirit** » Sun Jun 28, 2009 9:00 pm

Thanks for the help Bloodthirsty.... do you think you can post that script? I find it hard to visualize stuff having to do with programming.

Thanks.

Faalen · Post by **Faalen** » Mon Jun 29, 2009 12:10 am

Code: Select all

if ( MenuMode == 1 )
     return
endif

if ( OnActivate == 1 )
     MessageBox "Choose an option", "Yes", "No"
     set messageOn to 1
endif

if ( messageOn == 1 )
     set button to GetButtonPressed
     if ( button == -1 )
          return
     elseif ( button == 0 )
          MessageBox "You chose yes"
          set messageOn to 0
          return
     elseif ( button == 1 )
          MessageBox "You chose no"
          set messageOn to 0
          return
     endif
endif

messageOn needs to be declared as a variable. The problem you were originally having is that it takes several frames for a button to return, far more than the one allowed by the script. Also, frames process in MenuMode, so the time it takes the player to select counts.

Flawed Spirit · Post by **Flawed Spirit** » Mon Jun 29, 2009 12:43 am

It's so simple when you really look at it. Now that I have this, I think I can expand it to suit my needs. Thanks.