lines like 

"TR_m1_noga-togroi"->set gotX to ( GetPos, X )

should be e.g.

set gotX to ( "TR_m1_noga-togroi"->GetPos X )

Personally I would change the script like this:

begin TR_m1_q_TO_ACK_20

; This script was formerly called TR_m1_q_TO_ACK-20. I have renamed it due to the problems
; that dashes can cause in script names (at least in OpenMW). -- arvisrend, 29 May 2013

float gotX
float gotY
float gotZ

;this is the script that makes Noga-Togroi appear to the player 
;it also moves Devas Terano to Bal Oyra.

;the following chunk of script is the part that makes Noga-Togroi teleport to the player. There are four locations where the confrontation can take place
;the locations are: the transport ship, the river strider, the silt strider and the road exit

if ( MenuMode )
    return
endif

if ( GetPCCell "Tel Ouada" )    
else
    return
endif

float t1
if ( t1 < 2.1 )
    set t1 to ( t1 + GetSecondsPassed )
    return
endif
set t1 to Random 1001
set t1 to ( t1 * 0.0002 ) ; 0 <= t1 <= 0.2, so next 1.9 <= delay <= 2.1

if ( player->GetDistance "TR_m1_Dunveri_Rodran" <= 600 ) ; if PC is near the ship transport NPC...
; FIRST LOCATION BY THE SHIP ; No longer exists as travel service after TR 1709 restored for OldTravels and 1709hotfix since that exit route is now still available here
    "TR_m1_noga-togroi"->PositionCell 202528 151808 200 0 "Tel Ouada" ; ...Noga will appear there
    "TR_m1_Dunveri_Rodran"->Say "vo\d\m\bFle_DM001.mp3" "Help! A beast!" ; the ship's captain reacts accordingly

elseif ( player->GetDistance "TR_m1_Aamunos_Rolvar" <= 600 ) ; if PC is near the river strider transport NPC...
    "TR_m1_noga-togroi"->PositionCell 205466 153362 128 200 "Tel Ouada" ; ...Noga will appear there
    "TR_m1_Aamunos_Rolvar"->Say "vo\d\m\bFle_DM001.mp3" "Help! A beast!"

elseif ( player->GetDistance "TR_m1_Varusha Caril" <= 600 ) ; if PC is near the silt strider NPC...
    "TR_m1_noga-togroi"->PositionCell 208290 152839 904 325 "Tel Ouada"

elseif ( player->GetDistance "TR_m1_Q_TO_ACK-20act" <= 600 ) ; if PC tries to hit the road to exit Tel Ouada
    "TR_m1_noga-togroi"->PositionCell 212288 148064 256 325 "Tel Ouada"

else
    return ; skip invariant part below
endif

"TR_m1_Devas_Terano"->PositionCell 3680 4384 40 2 "Bal Oyra, The Black Ogre Tavern" ; Devas Terano gets teleported to a tavern in Bal Oyra
PlaySoundVP "mysticism hit" 0.5 1.0 ; a sound effect is played
set gotX to ( "TR_m1_noga-togroi"->GetPos X ) ; this following part creates a visual effect
set gotY to ( "TR_m1_noga-togroi"->GetPos Y )
set gotZ to ( "TR_m1_noga-togroi"->GetPos Z )
set gotZ to ( gotZ - 40 )
"TR_m1_noga-togroi"->Placeitem "sprigganup" gotX gotY gotZ 0 ; it uses the same effect as BM spriggans and werewolves.
StartScript TR_m1_q_TO_ACK_nogatalk ; global talk script is launched
StopScript TR_m1_q_TO_ACK_20 ; and the script is stopped altogether

end