begin T_ScObj_LightCaveRay_Script

short init
short moving
short daytime
short daytimebefore
float origX
float origY
float origZ
float altX
float altY
float altZ
long movZ

if ( MenuMode == 1 )        ; skip for menu mode
    return
endif

if ( init == 0 )                ; setup values
    Move, Z, 36000    
    set origX to GetStartingPos, X
    set origY to GetStartingPos, Y
    set origZ to GetStartingPos, Z
    set altX to GetPos, X
    set altY to GetPos, Y
    set altZ to GetPos, Z
    set moving to -1
    set init to 1
endif

if ( GameHour >= 20 )
    set daytime to -1        ; night
elseif ( GameHour >= 19 )
    set daytime to -2        ; dusk
elseif ( GameHour >= 8 )
    set daytime to 1        ; day
elseif ( GameHour >= 7 )
    set daytime to 2        ; dawn
else
    set daytime to -1        ; night
endif

if ( daytime == 2 )
    if ( daytimebefore != 2 )
        SetPos, X, altX
        SetPos, Y, altY
        SetPos, Z, altZ
        set moving to 1
        set movZ to 36000
    endif
elseif ( daytime == -2 )
    if ( daytimebefore != -2 )
        SetPos, X, origX
        SetPos, Y, origY
        SetPos, Z, origZ
        set movZ to 5
        set moving to 1
    endif
elseif ( daytime == 1 )
    if ( daytimebefore != 1 )
        if ( moving == -1 )     ; not already moving
            SetPos, X, origX
            SetPos, Y, origY
            SetPos, Z, origZ
            set movZ to 5
            set moving to 0
        endif
    endif
else if ( daytime == -1 )
    if ( daytimebefore != -1 )
        if ( moving == -1 )     ; not already moving
            SetPos, X, altX
            SetPos, Y, altY
            SetPos, Z, altZ
            set movZ to 36000
            set moving to 0
        endif
    endif
endif

set daytimebefore to daytime ; update time

if ( moving == 1 )
    if ( daytime > 0 )
        Move, Z, -5
        set movZ to movZ - 5
    else
        Move, Z, 5
        set movZ to movZ + 5
    endif
    if ( movZ > 36000 ) ; reached night pos
        set moving to -1
    elseif ( movZ < 5 ) ; reached day pos
        set moving to -1 
    endif
endif

end